Inhoud

# Informatiefuncties

Deze categorie bevat de Informatie functies.

Om toegang te krijgen tot deze functie..

Invoegen - Functie - Categorie Informatie

De gegevens in de volgende tabel dienen als basis voor een aantal voorbeelden in de beschrijvingen van de functie:

| C | D
2 | X-waarde | y-waarde
3 | -5 | -3
4 | -2 | 0
5 | -1 | 1
6 | 0 | 3
7 | 2 | 4
8 | 4 | 6
9 | 6 | 8

## ALS.FOUT

Test op foutvoorwaarden, inclusief de foutwaarde #N/B, en geeft WAAR of ONWAAR terug.

Als er een fout optreedt, wordt met de functie een logische of numerieke waarde als resultaat gegeven.

#### Syntaxis

ALS.FOUT(Waarde; Alternatieve waarde)

Waarde is of verwijst naar de waarde die moet worden getest. ISFOUT() geeft WAAR terug als er een fout is en ONWAAR als dat niet zo is.

#### Voorbeeld

=ALS.FOUT(C8;C9), als cel C8 =1/0 bevat, geeft de waarde C9, omdat 1/0 een foutwaarde geeft.

=ALS.FOUT(C8;C9), als cel C8 13 bevat, geeft 13 de waarde van C8, wat geen fout is.

## ALS.NB

Geeft WAAR als een cel de foutwaarde #N/B (waarde niet beschikbaar) bevat.

De functie geeft ONWAAR terug indien er een fout optreedt.

#### Syntaxis

ALS.NB(Waarde)

Waarde is de waarde of expressie die getest moet worden.

#### Voorbeeld

=ALS.NB(D3) geeft ONWAAR als resultaat.

## ALSFOUT

Retourneert de waarde als de cel geen foutwaarde bevat, of de alternatieve waarde als dit wel het geval is.

Deze functie is beschikbaar sinds LibreOffice 4.0.

#### Syntaxis

ALSFOUT(Waarde; Alternatieve waarde)

Waarde is de waarde of uitdrukking die gegeven wordt als het niet gelijk is of resulteert in een fout.

Alternatieve_waarde is de waarde of uitdrukking die gegeven wordt als de expressie of waarde van Waarde gelijk is of een fout geeft.

#### Voorbeeld

=ALSFOUT(C8;C9) als cel C8 =1/0 bevat, geeft de waarde C9, omdat 1/0 een fout is.

ALSFOUT(C8;C9) als cel C8 13 bevat, geeft 13 de waarde van C8, wat geen fout is.

## ALSNB

Retourneert de waarde als de cel de foutwaarde #N/A (waarde niet beschikbaar) niet bevat, of de alternatieve waarde als dit wel het geval is.

Deze functie is beschikbaar sinds LibreOffice 4.0.

#### Syntaxis

ALSNB(Waarde; Alternatieve waarde)

Waarde is de waarde of expressie die gegeven wordt als het niet gelijk is of in een #N/A-fout resulteert.

Alternatieve_waarde is de waarde of expressie die gegeven wordt als de expressie of waarde van Waarde gelijk is of in een #N/A-fout resulteert.

#### Voorbeeld

=ALSNB(D3;D4) geeft de waarde D3 als D3 niet in een #N/B-fout eindigt of D4 als het dit wel doet.

## CEL

Geeft informatie over adres, opmaak of inhoud van een cel.

#### Syntaxis

CEL("Infotype" ; Verwijzing (optioneel))

Infotype is de tekenreeks die het type informatie specificeert. De tekenreeks is altijd in het Engels. Hoofd- of kleine letters is optioneel.

Infotype | Betekenis
--- | ---
COL | Geeft het nummer van de kolom waarnaar verwezen wordt. =CEL("COL";D2) geeft 4 terug.
ROW | Geeft het nummer van de rij waarnaar verwezen wordt. =CEL("ROW";D2) geeft 2 terug.
SHEET | Geeft het getal van het blad waarnaar verwezen wordt. =CEL("Sheet";Blad3.D2) geeft 3 terug.
ADDRESS | Geeft het absolute adres van de cel waarnaar verwezen wordt. =CEL("ADDRESS";D2) geeft $D$2 terug. =CEL("ADDRESS";Blad3.D2) geeft $Blad3.$D$2 terug. =CEL("ADDRESS";'X:\dr\test.sxc'#$Blad1.D2) geeft 'file:///X:/dr/test.sxc'#$Blad1.$D$2 terug.
FILENAME | Geeft de bestandsnaam en het bladnummer van de cel waarnaar verwezen wordt. =CEL("FILENAME";D2) geeft 'file:///X:/dr/own.sxc'#$Blad1 terug als de formule in het huidige document X:\dr\own.sxc aanwezig is op Blad1. =CEL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) geeft 'file:///X:/dr/test.ods'#$Blad1 terug.
COORD | Geeft het volledige celadres in Lotus™-notatie. =CEL("COORD"; D2) geeft $A:$D$2 terug. =CEL("COORD"; Blad3.D2) geeft $C:$D$2 terug.
CONTENTS | Geeft de inhoud van de cel waarnaar verwezen wordt, zonder enige opmaak.
TYPE | Geeft het type celinhoud. b = blank. lege cel l = label. Tekst, resultaat van een formule als tekst v = waarde. Waarde, resultaat van een formule als getal
WIDTH | Geeft de breedte van de kolom waarnaar verwezen wordt. De eenheid is het aantal nullen (0) dat in de kolom past in de standaardtekst en de standaardgrootte.
PREFIX | Geeft de uitlijning van de cel waarnaar verwezen wordt. ' = links uitlijnen of links uitgevuld " = rechts uitlijnen ^ = gecentreerd \ = herhaling (momenteel niet actief)
PROTECT | Geeft de status van de celbeveiliging voor de cel. 1 = cel is beveiligd 0 = cel is niet beveiligd

FORMAT

Geeft een tekenreeks die de getalopmaak aanduidt.

, = getal met scheidingsteken voor duizendtallen

F = getal zonder scheidingsteken voor duizendtallen

C = valuta-opmaak

S = exponentiële voorstelling, bijvoorbeeld 1,234+E56

P = procent

In de bovenstaande opmaak wordt het aantal decimalen na het decimale scheidingsteken als getal gegeven. Voorbeeld: de getalopmaak #,##0,0 geeft ,1 en de getalopmaak 00,000% geeft P3

D1 = MMM-D-JJ, MM-D-JJ en gelijksoortige notaties

D2 = DD-MM

D3 = MM-JJ

D4 = DD-MM-JJJJ UU:MM:SS

D5 = MM-DD

D6 = UU:MM:SS AM/PM

D7 = UU:MM AM/PM

D8 = UU:MM:SS

D9 = UU:MM

G = Alle andere notaties

- (minteken) aan het einde = negatieve getallen worden in kleur opgemaakt

() (haakjes) aan het eind = er is een haakje openen in de notatiecode

COLOR | Geeft 1 als de negatieve waardes met kleur zijn opgemaakt, anders 0.
PARENTHESES | Geeft 1 als resultaat als de notatiecode een haakje openen ( bevat, en anders 0.

Verwijzing (optioneel) (lijst met opties) is de positie van de cel die bekeken moet worden. Als Verwijzing een bereik is, wordt de cel linksboven van het bereik geplaatst. Als Verwijzing ontbreekt, gebruikt LibreOffice Calc de positie van de cel waarin deze formule staat. Microsoft Excel gebruikt de verwijzing van de cel waarin de cursor staat.

## FORMULETEKST

Geeft de formule van een formule cel terug als een tekenreeks.

Deze functie wordt altijd opnieuw berekend wanneer er een herberekening plaatsvindt.

#### Syntaxis

FORMULETEKST(Verwijzing)

Verwijzing is een verwijzing naar een cel die een formule bevat.

Een ongeldige verwijzing of een verwijzing naar een cel zonder formule resulteert in de foutwaarde #N/B.

#### Voorbeeld

Als cel A8 de formule =SOM(1;2;3) bevat dan

=FORMULETEKST(A8) geeft de tekst =SOM(1;2;3) terug.

## HUIDIG

Deze functie geeft als resultaat de evaluatie van de formule waarvan het deel uitmaakt tot op de huidige datum (met andere woorden: het resultaat tot op het moment waarop de evaluatie is beland). Samen met de functie STIJL() is het voornaamste gebruik om geselecteerde opmaakprofielen op een cel toe te passen, afhankelijk van de celinhoud.

#### Syntaxis

HUIDIG()

#### Voorbeeld

=1+2+HUIDIG()

Het voorbeeld geeft 6 terug. De formule wordt berekend van links naar rechts als: 1 + 2 is gelijk aan 3, het resultaat berekenend tot de datum waarop HUIDIG() wordt tegengekomen; HUIDIG() levert daarom 3 op, hetgeen wordt opgeteld bij de originele 3 om uit te komen op 6.

=A2+B2+STIJL(ALS(HUIDIG()>10;"Slecht";"Standaard"))

Het voorbeeld geeft A2 + B2 terug (STIJL) geeft hier 0 terug). Het opmaakprofiel Slecht wordt op de cel toegepast als de som groter is dan 10. Zie de functie STIJL voor meer uitleg.

="choo"&HUIDIG()

Het voorbeeld geeft choochoo terug.

#### Technische informatie

Deze functie maakt geen deel uit van de Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula) indeling standaard. De naamafstand is

ORG.OPENOFFICE.CURRENT

## INFO

Geeft specifieke informatie over de huidige werkomgeving. De functie ontvangt één tekstargument en retourneert gegevens afhankelijk van die parameter.

Deze functie wordt altijd opnieuw berekend wanneer er een herberekening plaatsvindt.

#### Syntaxis

INFO("Type")

De volgende tabel somt de waardes op voor de tekstparameter Type en de teruggegeven waardes voor de functie INFO.

Waarde voor "Type" | Teruggeven waarde
--- | ---
"osversion" | Altijd "Windows (32-bit) NT 5.01", om compatibiliteitsredenen

"system"

Het type besturingssysteem:
"ANDROID" voor het mobiele besturingssysteem van Google
"DRAGONFLY" voor het DragonFly-besturingssysteem afgeleid van FreeBSD
"EMSCRIPTEN" voor browser WebAssembly-systeem
"FREEBSD ", "OPENBSD" of "NETBSD" voor besturingssystemen gebaseerd op Berkeley Software Distribution (BSD)
"HAIKU" voor BeOS-compatibel besturingssysteem
"iOS" voor mobiel Apple-besturingssysteem
" LINUX" voor op GNU/Linux gebaseerde besturingssystemen
"MACOSX" voor Apple macOS
"SOLARIS" voor Oracle Solaris besturingssysteem
"WNT" voor Microsoft Windows

"release" | De ID van de productuitgave, bijvoorbeeld "300m25(Build:9876)"
"numfile" | Altijd 1, om compatibiliteitsredenen
"recalc" | Huidige modus voor herberekening van formules: "Automatisch" of "Handmatig" (gelokaliseerd in LibreOffice-taal)

Andere werkbladtoepassingen kunnen gelokaliseerde waardes accepteren voor de parameter Type, maar LibreOffice Calc zal alleen de Engelse waardes accepteren.

#### Voorbeeld

=INFO("release") geeft het uitgavenummer van het gebruikte LibreOffice product.

=INFO(D5) waarbij cel D5 de tekenreeks system bevat, geeft het type van het besturingssysteem terug.

## IS.EVEN

Geeft WAAR als de waarde een even geheel getal is, of ONWAAR als de waarde oneven is.

#### Syntaxis

IS.EVEN(Waarde)

Waarde is de waarde die gecontroleerd moet worden.

Elk cijfer achter de komma wordt genegeerd als Waarde geen geheel getal is. Het teken van Waarde wordt ook genegeerd.

#### Voorbeeld

=IS.EVEN(48) geeft WAAR terug

=IS.EVEN(33) geeft ONWAAR terug

=IS.EVEN(0) geeft WAAR terug

=IS.EVEN(-2,1) geeft WAAR terug

=IS.EVEN(3,999) geeft ONWAAR terug

## IS.EVEN_ADD

Test op even getallen. Retourneert 1 als het getal, gedeeld door 2, een heel getal oplevert.

De functies waarvan de namen eindigen op _ADD of Excel2003 leveren dezelfde resultaten op als de overeenkomende functies in Microsoft Excel 2003. Gebruik de functies zonder toevoeging om resultaten te verkrijgen die op internationale standaarden gebaseerd zijn.

#### Syntaxis

IS.EVEN_ADD(Getal)

Getal is het getal dat moet worden getest.

#### Voorbeeld

=IS.EVEN_ADD(5) geeft 0 terug.

=IS.EVEN_ADD(A1) geeft 1 terug als cel A1 het getal 2 bevat.

## IS.ONEVEN

Geeft WAAR als de waarde oneven is, of ONWAAR als het getal even is.

#### Syntaxis

IS.ONEVEN(Waarde)

Waarde is de waarde die gecontroleerd moet worden.

Elk cijfer achter de komma wordt genegeerd als Waarde geen geheel getal is. Het teken van Waarde wordt ook genegeerd.

#### Voorbeeld

=IS.ONEVEN(33) geeft WAAR terug

=IS.ONEVEN(48) geeft ONWAAR terug

=IS.ONEVEN(3,999) geeft WAAR terug

=IS.ONEVEN(-3,1) geeft WAAR terug

## IS.ONEVEN_ADD

Geeft WAAR (1) als het getal geen heel getal geeft wanneer het door 2 gedeeld wordt.

De functies waarvan de namen eindigen op _ADD of Excel2003 leveren dezelfde resultaten op als de overeenkomende functies in Microsoft Excel 2003. Gebruik de functies zonder toevoeging om resultaten te verkrijgen die op internationale standaarden gebaseerd zijn.

#### Syntaxis

IS.ONEVEN_ADD(Getal)

Getal is het getal dat moet worden getest.

#### Voorbeeld

=IS.ONEVEN_ADD(5) geeft 1 terug.

## ISFORMULE

Geeft WAAR als de cel een formulecel is.

Als er een fout optreedt, wordt met de functie een logische of numerieke waarde als resultaat gegeven.

#### Syntaxis

ISFORMULE(Verwijzing)

Verwijzing duidt de verwijzing naar een cel aan waarin een test zal worden uitgevoerd om te bepalen of deze een formule bevat.

#### Voorbeeld

=ISFORMULE(C4) geeft ONWAAR terug als de cel C4 het getal 5 bevat.

## ISFOUT2

Test op foutvoorwaarden, uitgezonderd de foutwaarde #N/B, en geeft WAAR of ONWAAR terug.

Als er een fout optreedt, wordt met de functie een logische of numerieke waarde als resultaat gegeven.

#### Syntaxis

ISFOUT2(Waarde)

Waarde is elke waarde of uitdrukking die getest is om te zien of een andere foutwaarde dan #N/B aanwezig is.

#### Voorbeeld

=ISFOUT2(C8) waar cel C8 =1/0 bevat, geeft WAAR terug, omdat 1/0 een fout is.

=ISFOUT2(C9) waar cel C9 =NB() bevat geeft ONWAAR terug, omdat ISFOUT2() de fout #N/B negeert.

## ISGEENTEKST

Hiermee wordt getest of de celinhoud uit tekst of getallen bestaat en geeft ONWAAR als de inhoud tekst is.

De functie geeft WAAR terug indien er een fout optreedt.

#### Syntaxis

ISGEENTEKST(Waarde)

Waarde is elke waarde of expressie waar een test wordt uitgevoerd om te bepalen of het om een tekst, getallen of een Booleaanse waarde gaat.

#### Voorbeeld

=ISGEENTEKST(D2) geeft ONWAAR terug als cel D2 de tekst abcdef bevat.

=ISGEENTEKST(D9) geeft WAAR terug als cel D9 het getal 8 bevat.

## ISGETAL

Geeft WAAR als de waarde naar een getal verwijst.

Als er een fout optreedt, wordt met de functie een logische of numerieke waarde als resultaat gegeven.

#### Syntaxis

ISGETAL(Waarde)

Waarde is een expressie die getest moet worden om te bepalen of het een getal of tekst is.

#### Voorbeeld

=ISGETAL(C3) geeft WAAR terug als de cel C3 het getal 4 bevat.

=ISGETAL(C2) geeft ONWAAR terug als de cel C2 de tekst abcdef bevat.

## ISLEEG

Geeft WAAR als de verwijzing naar een cel leeg is. Met deze functie wordt bepaald of de inhoud van een cel leeg is. Een cel waarin een formule staat, is niet leeg.

Als er een fout optreedt, wordt met de functie een logische of numerieke waarde als resultaat gegeven.

#### Syntaxis

ISLEEG(Waarde)

Waarde is de inhoud die getest moet worden.

#### Voorbeeld

=ISLEEG(D2) geeft ONWAAR als resultaat als cel D2 de tekst abcdef bevat.

## ISLOGISCH

Test op een logische waarde (WAAR of ONWAAR).

De functie geeft ONWAAR terug indien er een fout optreedt.

#### Syntaxis

ISLOGISCH(Waarde)

Geeft WAAR terug als Waarde een logische waarde is (WAAR of ONWAAR), en geeft anders ONWAAR terug.

#### Voorbeeld

=ISLOGISCH(99) geeft ONWAAR terug, omdat 99 een getal is en geen logische waarde.

=ISLOGISCH(ISNB(D4)) geeft WAAR terug, ongeacht de inhoud van cel D4, omdat ISNB() een logische waarde teruggeeft.

## ISTEKST

Geeft WAAR als de celinhoud naar tekst verwijst.

De functie geeft ONWAAR terug indien er een fout optreedt.

#### Syntaxis

ISTEKST(Waarde)

Waarde is een waarde, getal, Booleaanse waarde of een foutwaarde die getest moet worden.

#### Voorbeeld

=ISTEKST(D9) geeft WAAR terug als cel D9 de tekst abcdef bevat.

=ISTEKST(C3) geeft ONWAAR terug als cel C3 het getal 3 bevat.

## ISVERWIJZING

Test of het argument een verwijzing is. Geeft WAAR terug als het argument een verwijzing is, anders geeft het ONWAAR terug. Als een verwijzing wordt opgegeven dan berekent deze functie de waarde niet waarnaar wordt verwezen.

Als er een fout optreedt, wordt met de functie een logische of numerieke waarde als resultaat gegeven.

#### Syntaxis

ISVERWIJZING(Waarde)

Waarde is de waarde die getest moet worden om te bepalen of het een verwijzing is.

#### Voorbeeld

=ISVERWIJZING(C5) geeft het resultaat WAAR terug, omdat C5 een geldige verwijzing is.

=ISVERWIJZING("abcdef") geeft altijd ONWAAR terug omdat een tekst nooit een verwijzing kan zijn.

=ISVERWIJZING(4) geeft ONWAAR terug omdat een getal nooit een verwijzing kan zijn.

=ISVERWIJZING(INDIRECT("A6")) geeft WAAR terug, omdat INDIRECT een functie is die een verwijzing teruggeeft.

=ISVERWIJZING(ADRES(1; 1; 2;"Blad2")) geeft ONWAAR terug, omdat ADRES een functie is die een tekst teruggeeft, hoewel het lijkt op een verwijzing.

## N

Geeft de numerieke waarde van een gegeven parameter terug. Geeft 0 wanneer de parameter tekst of ONWAAR is.

Wanneer een fout optreedt, zal de functie een foutwaarde teruggeven.

#### Syntaxis

N(Waarde)

Waarde is de parameter die moet worden omgezet in een getal. N() geeft de numerieke waarde als het mogelijk is. Het geeft de logische waardes WAAR en ONWAAR respectievelijk als 1 en 0. Het geeft tekst als 0 terug.

#### Voorbeeld

=N(123) geeft 123 terug

=N(WAAR()) geeft 1 terug

=N(ONWAAR()) geeft 0 terug

=N("abc") geeft 0 terug

=N(1/0) geeft #DELING.DOOR.0! terug

## NB

Geeft als resultaat de foutwaarde #N/B.

#### Syntaxis

NB()

#### Voorbeeld

=NB() converteert de inhoud van de cel naar #N/B.

## TYPE

Geeft het type van de waarde, waar 1 = getal, 2 = tekst, 4 = booleaanse waarde, 8 = formule, 16 = foutwaarde, 64 = matrix.

Als er een fout optreedt, wordt met de functie een logische of numerieke waarde als resultaat gegeven.

#### Syntaxis

TYPE(Waarde)

Waarde is een specifieke waarde waarvan het gegevenstype is vastgesteld.

### Voorbeeld (zie voorbeeldtabel hierboven)

=TYPE(C2) geeft 2 terug als resultaat.

=TYPE(D9) geeft 1 terug als resultaat.

Verwante onderwerpen

Functies per categorie